# Only build binary for current platform.
build-only-bin:
  goreleaser build --snapshot --clean --single-target --config ./build/release.yaml

# Build binaries, packages, docker images for all platforms.
build:
  goreleaser release --snapshot --clean --config ./build/release.yaml

# Unstable release process.
unstable:
  #!/bin/env bash
  set -exuo pipefail
  export DOCKER_REGISTRY={{ DOCKER_REGISTRY }}

  goreleaser release --clean --snapshot --config ./build/release.yaml

  IMAGES=$(docker image ls --format "{{'{{ .Repository }}:{{ .Tag }}'}}" | grep -e "{{ DOCKER_IMAGE }}.*")

  for image in ${IMAGES}; do
    docker push ${image}
  done

  docker manifest create {{ DOCKER_IMAGE }} ${IMAGES}
  docker manifest push {{ DOCKER_IMAGE }}

# Stable release process.
release:
  goreleaser release --clean --config ./build/release.yaml
